有您的持续关注
我们会做得更好

零滞后ZeroLag_MACD指标



ZeroLag+MACD指标是MACD指标优化的一种,图表效果如下:ZeroLag MACD指标

关于Zero Lag MACD的说明引用如下文字:

Zero Lag MACD是运用零滞后移动平均线来计算MACD平滑异同平均指标所得的技术指标。

MACD是股票技术分析中最常用到的一个趋势型指标,但是它有一个特点:有滞后性。为了克服这个弱点,就有了Zero Lag MACD指标。

零滞后MACD的计算公式:

ZLMACD=(2*EMA(C,SN)-EMA(EMA(C,SN),SN))-(2*EMA(C,LP)-EMA(EMA(C,LP),LP));

ZLMACDS=2*EMA(ZLMACD,M)-EMA(EMA(ZLMACD,M),M);

其中,

EMA是指数移动平均;

SN是短周期数,例如12;

LP是长周期数,例如26;

M是信号线对ZLMACD的平滑周期,例如9;

ZLMACDS是信号线。

零滞后MACD的使用方法:

这个指标的用法与普通的MACD指标用法相似。例如,当Zero Lag MACD上穿0轴或是信号线,买入;下穿0轴或是信号线,卖出。但是,因为它在计算中使用来零滞后移动均线(double exponential moving average, DEMA)而不是指数移动均线,所以它比较敏感,可以很快地反映价格走势的变化。所以,这种改进可能可以优化基于MACD指标的交易系统。
但是,必须注意,一个灵敏的指标往往会产生更多的假信号。所以,在构建股票交易系统时,要了解各个指标的优缺点,然后根据交易策略的需要,而进行取舍,当然还要经过系统测试。并不一定新的指标就比老的好。技术指标是死的,但是人是活的。所以,重要的不是技术指标本身,而是使用指标的人。

ZeroLag+MACD指标源码如下:

//+------------------------------------------------------------------+
//|                                                 ZeroLag MACD.mq4 |
//|                                     Copyright 2016, QQ:125808047 |
//+------------------------------------------------------------------+
#property copyright "www.125808047.com"
#property link      "http://www.125808047.com/"
//----
#property indicator_separate_window
#property  indicator_buffers 2
#property indicator_color1 Blue
#property indicator_color2 Red
//---- input parameters
extern int FastEMA = 12;
extern int SlowEMA = 24;
extern int SignalEMA = 9;
//---- buffers
double MACDBuffer[];
double SignalBuffer[];
double FastEMABuffer[];
double SlowEMABuffer[];
double SignalEMABuffer[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- indicators
   IndicatorBuffers(5);
   SetIndexBuffer(0, MACDBuffer);
   SetIndexBuffer(1, SignalBuffer);
   SetIndexBuffer(2, FastEMABuffer);
   SetIndexBuffer(3, SlowEMABuffer);
   SetIndexBuffer(4, SignalEMABuffer);
   SetIndexStyle(0, DRAW_HISTOGRAM);
   SetIndexStyle(1, DRAW_LINE,EMPTY);
   SetIndexDrawBegin(0, SlowEMA);
   SetIndexDrawBegin(1, SlowEMA);
   IndicatorShortName("ZeroLag MACD(" + FastEMA + "," + SlowEMA + "," + SignalEMA + ")");
   SetIndexLabel(0, "MACD");
   SetIndexLabel(1, "Signal");
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   int limit;
   int counted_bars = IndicatorCounted();
   if(counted_bars < 0) 
       return(-1);
   if(counted_bars > 0) 
       counted_bars--;
   limit = Bars - counted_bars;
   double EMA, ZeroLagEMAp, ZeroLagEMAq;
   for(int i = 0; i < limit; i++)
     {
       FastEMABuffer[i] = iMA(NULL, 0, FastEMA, 0, MODE_EMA, PRICE_CLOSE, i);
       SlowEMABuffer[i] = iMA(NULL, 0, SlowEMA, 0, MODE_EMA, PRICE_CLOSE, i);
     }
   for(i = 0; i < limit; i++)
     {
        EMA = iMAOnArray(FastEMABuffer, Bars, FastEMA, 0, MODE_EMA, i);
        ZeroLagEMAp = FastEMABuffer[i] + FastEMABuffer[i] - EMA;
        EMA = iMAOnArray(SlowEMABuffer, Bars, SlowEMA, 0, MODE_EMA, i);
        ZeroLagEMAq = SlowEMABuffer[i] + SlowEMABuffer[i] - EMA;
        MACDBuffer[i] = ZeroLagEMAp - ZeroLagEMAq;
     }
   for(i = 0; i < limit; i++)
       SignalEMABuffer[i] = iMAOnArray(MACDBuffer, Bars, SignalEMA, 0, MODE_EMA, i);
   for(i = 0; i < limit; i++)
     {
       EMA = iMAOnArray(SignalEMABuffer, Bars, SignalEMA, 0, MODE_EMA, i);
       SignalBuffer[i] = SignalEMABuffer[i] + SignalEMABuffer[i] - EMA;
     }
   return(0);
  }
//+------------------------------------------------------------------+

如您喜欢此文章请点下面分享按钮↴峰汇在线 » 零滞后ZeroLag_MACD指标
上一篇:
下一篇:
分享到:更多 ()