诚信为本
量力而为
当前位置:峰汇在线 > MQL语言 > MQL5编程参考文档 > 正文

2.1.6 图表属性设置函数示例

本节包含图表属性工作的示例。每个属性显示一到两个完整的函数。这些函数允许设置/接收属性的值。这些函数在自定义mql5应用程序中可以被使用”as is”。
下面的截图举例说明地展示了如何改变图表属性表现的图形面板。点击下一步可以设置新的适当属性的值和查看图表窗口的变化。使用图表示例

图表属性和使用它们的样本函数
CHART_IS_OBJECT 定义对象是否是真实图表或是图形对象。

//+------------------------------------------------------------------+ 
//| 定义对象是否是图表。如果它是                                          | 
//| 图形对象,则结果为true。如果它是真实                                   | 
//| 图表,则结果变量为false值。                                           | 
//+------------------------------------------------------------------+ 
bool ChartIsObject(bool &result,const long chart_ID=0) 
  { 
//--- 准备变量获得属性值 
   long value; 
//--- 重置错误的值 
   ResetLastError(); 
//--- 获得图表属性 
   if(!ChartGetInteger(chart_ID,CHART_IS_OBJECT,0,value)) 
     { 
      //--- 在EA日志显示错误信息 
      Print(__FUNCTION__+", Error Code = ",GetLastError()); 
      //--- 返回 false 
      return(false); 
     } 
//--- 在内存中存储图表属性的值 
   result=value; 
//--- 成功执行 
   return(true); 
  }

CHART_BRING_TO_TOP 显示所有其他图表的顶部的图表。

//+----------------------------------------------------------------------+ 
//| 发送命令到程序端展示所有其他图表上面的图表。                                | 
//+----------------------------------------------------------------------+ 
bool ChartBringToTop(const long chart_ID=0) 
  { 
//--- 重置错误的值 
   ResetLastError(); 
//--- 显示所有其他图表的顶部的图表 
   if(!ChartSetInteger(chart_ID,CHART_BRING_TO_TOP,0,true)) 
     { 
      //--- 在EA日志显示错误信息 
      Print(__FUNCTION__+", Error Code = ",GetLastError()); 
      return(false); 
     } 
//--- 成功执行 
   return(true); 
  }

CHART_MOUSE_SCROLL 使用鼠标左键滚动图表的属性。

//+--------------------------------------------------------------------------+ 
//| 该函数定义了使用鼠标左键滚动图表是否                                          | 
//| 被启用。                                                                   | 
//+--------------------------------------------------------------------------+ 
bool ChartMouseScrollGet(bool &result,const long chart_ID=0) 
  { 
//--- 准备变量获得属性值 
   long value; 
//--- 重置错误的值 
   ResetLastError(); 
//--- 接收属性值 
   if(!ChartGetInteger(chart_ID,CHART_MOUSE_SCROLL,0,value)) 
     { 
      //--- 在EA日志显示错误信息 
      Print(__FUNCTION__+", Error Code = ",GetLastError()); 
      return(false); 
     } 
//--- 在内存中存储图表属性的值 
   result=value; 
//--- 成功执行 
   return(true); 
  } 
//+--------------------------------------------------------------------+ 
//| 该函数启用/禁用使用鼠标左键滚动图表。                                    | 
//+--------------------------------------------------------------------+ 
bool ChartMouseScrollSet(const bool value,const long chart_ID=0) 
  { 
//--- 重置错误的值 
   ResetLastError(); 
//--- 设置属性值 
   if(!ChartSetInteger(chart_ID,CHART_MOUSE_SCROLL,0,value)) 
     { 
      //--- 在EA日志显示错误信息 
      Print(__FUNCTION__+", Error Code = ",GetLastError()); 
      return(false); 
     } 
//--- 成功执行 
   return(true); 
  }
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20
打赏
版权所有转载请注明标题及链接:峰汇在线 » 2.1.6 图表属性设置函数示例
上一篇:
下一篇:
分享到: 更多 (0)

如您觉得此文不错请扫码打赏!

支付宝扫一扫打赏

微信扫一扫打赏